import("fft.lib");
import("fft2d.lib");

DILATION_MIN = 0;
EROSION_MAX = 255;

strel_shift_dilation = DILATION_MIN : vectorize(1);
strel_shift_erosion = EROSION_MAX : vectorize(1);

spray_by_three(n) = _ <: par(i, n, ([i], [i+1], [i+2]));

tri_max = max, _ : max;
tri_maxs(n) = par(i, n, tri_max);
tri_min = min, _ : min;
tri_mins(n) = par(i, n, tri_min);

dilating(n) = strel_shift_dilation, _, strel_shift_dilation : #, _ : # : spray_by_three(n) : tri_maxs(n) : nconcat(n);
eroding(n) = strel_shift_erosion, _, strel_shift_erosion : #, _ : # : spray_by_three(n) : tri_mins(n) : nconcat(n);

//dilation(size, iter) = seq(i, iter, dilating(size));
//erosion(size, iter) = seq(i, iter, eroding(size));

dilation_square(x, y) = serialize : dilating(x) : vectorize(y) : matrix_transpose(y, x) : serialize : dilating(y) : vectorize(x) : matrix_transpose(x, y);

erosion_square(x, y) = serialize : eroding(x) : vectorize(y) : matrix_transpose(y, x) : serialize : eroding(y) : vectorize(x) : matrix_transpose(x, y);

cross = _, _ <: !, _, _, !;

//dilations(x, y, iter) = seq(i, iter, dilation_square(x,y));
//erosions(x, y, iter) = seq(i, iter, erosion_square(x,y));

dilations(x, y, iter) = _ : vectorize(y) : (iter, ((cross : ((0, 1 : prefix), _, _ : select2) : dilation_square(x, y))~_), (iter - 1)) : rdtable : serialize;
erosions(x, y, iter) = _ : vectorize(y) : (iter, ((cross : ((0, 1 : prefix), _, _ : select2) : erosion_square(x, y))~_), (iter - 1)) : rdtable : serialize;

opening(x, y, iter) = erosions(x, y, iter) : dilations(x, y, iter);
closing(x, y, iter) = dilations(x, y, iter) : erosions(x, y, iter);

threshold(x, n) = _, (n : vectorize(x)) : >;
and = *;

licenceplate(x, y, seuil) = _ <: (opening(x, y, 1), closing(x, y, 1) : threshold(x, seuil), threshold(x, seuil) : and : opening(x, y, 1) : dilations(x, y, 1)), _ : and;

//process = dilations(8, 8, 3);
//process = erosions(8, 8, 3);
//process = open(8, 8, 2);
//process = close(8, 8, 5);
//process = licenceplate(8, 8, 128);