X-Git-Url: https://scm.cri.ensmp.fr/git/Faustine.git/blobdiff_plain/c7f552fd8888da2f0d8cfb228fe0f28d3df3a12c..b4b6f2ea75b9f0f3ca918f5b84016610bf7a4d4f:/interpretor/preprocessor/faust-0.9.47mr3/tools/faust2pd/examples/faust/tester.dsp

diff --git a/interpretor/preprocessor/faust-0.9.47mr3/tools/faust2pd/examples/faust/tester.dsp b/interpretor/preprocessor/faust-0.9.47mr3/tools/faust2pd/examples/faust/tester.dsp
new file mode 100644
index 0000000..a80cc25
--- /dev/null
+++ b/interpretor/preprocessor/faust-0.9.47mr3/tools/faust2pd/examples/faust/tester.dsp
@@ -0,0 +1,36 @@
+declare name 		"tester";
+declare version 	"1.0";
+declare author 		"Grame";
+declare license 	"BSD";
+declare copyright 	"(c)GRAME 2006";
+
+//-----------------------------------------------
+// Tester : tests louspeakers
+// Send a test signal( sine, noise, pink) to one 
+// of 8 loudspeakers
+//-----------------------------------------------
+
+import("music.lib");
+
+pink	= f : (+ ~ g) with {
+	f(x) = 0.04957526213389*x - 0.06305581334498*x' + 0.01483220320740*x'';
+	g(x) = 1.80116083982126*x - 0.80257737639225*x';
+};
+
+
+// User interface
+//----------------
+smooth(c)		= *(1-c) : +~*(c);
+vol 			= hslider("(2)volume", -96, -96, 0, 0.1): db2linear : smooth(0.999);
+freq 			= hslider("(1) freq", 1000, 0, 24000, 0.1);
+dest 			= hslider("(3) destination", 0, 0, 8, 1);
+
+testsignal		= osci(freq)*checkbox("sine wave")
+				+ noise * checkbox("white noise")
+				+ pink(noise) * db2linear(20)  * checkbox("pink noise");
+
+process 		= vgroup( "Audio Tester", 
+					testsignal*vol 
+					<: par(i, 8, *(dest==i)) 
+				  );
+